Backus–Naur 范式

巴科斯–诺尔范式
术语名称	巴科斯–诺尔范式
英语名称	Backus–Naur form
别名	BNF, 巴克斯–瑙尔范式, 巴科斯范式, Backus normal form

巴科斯–诺尔范式(Backus–Naur form)或巴科斯范式(Backus normal form)，缩写为 BNF ，指一种为上下文无关文法设计的形式元语言语法。计算机领域中， BNF 及其变体作为编程语言理论的正式描述、作为语言文档及交流协议中的描述，得到广泛使用。

形式语言定义

定义形式语言的字母表和规则如下：

字母表

BNF 的字母表是以下集合的并集：

• 终结符的集合 [math]\displaystyle{ V_N }[/math] ，其中任意元素都是字面量。字面量形式上使用双引号包围，如 "abc" 等；特别地，允许出现空串 "" ，当需要双引号字符时可以使用单引号包围以免产生混淆 '"' ；
• 非终结符的集合 [math]\displaystyle{ V_T }[/math] 。非终结符使用连字符式并用尖括号包围，如 <symbol> 或 <a-symbol-with-a-long-name> ；
• 辅助符号的集合，包括竖线 | 和推导符号 ::= 。

规则

BNF 的公式由多个生成式组成，记生成式的集合为 [math]\displaystyle{ G }[/math] ，则 BNF 的公式为：

• [math]\displaystyle{ g,g_2,g_3,\cdots }[/math]，[math]\displaystyle{ g\in G }[/math]；

其中 [math]\displaystyle{ G }[/math] 为生成式集，是由符合以下形式的项构成的集合：

• [math]\displaystyle{ n ::= a_1 | a_2 | \cdots | a_r }[/math] ，其中 [math]\displaystyle{ n\in V_N, a_i\in A, r\in \mathbb{N}_+ }[/math] ；

其中 [math]\displaystyle{ A }[/math] 为生成式选项集，是由符合以下形式的项构成的集合：

• [math]\displaystyle{ v_1 v_2 \cdots v_s }[/math] ，其中 [math]\displaystyle{ v_i\in V_N \cup V_T, s\in \mathbb{N}_+ }[/math] 。

BNF 定义

这里使用 BNF 描述其自身的形式。并原教旨地展开字母和数字等在其他文档中通常被省略的定义。

<syntax>         ::= <rule> | <rule> <syntax>
<rule>           ::= <opt-whitespace> "<" <rule-name> ">" <opt-whitespace> "::=" <opt-whitespace> <expression> <line-end>
<opt-whitespace> ::= " " <opt-whitespace> | ""
<expression>     ::= <list> | <list> <opt-whitespace> "|" <opt-whitespace> <expression>
<line-end>       ::= <opt-whitespace> <EOL> | <line-end> <line-end>
<list>           ::= <term> | <term> <opt-whitespace> <list>
<term>           ::= <literal> | "<" <rule-name> ">"
<literal>        ::= '"' <text1> '"' | "'" <text2> "'"
<text1>          ::= "" | <character1> <text1>
<text2>          ::= "" | <character2> <text2>
<character>      ::= <letter> | <digit> | <symbol>
<letter>         ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J" | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"
<digit>          ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
<symbol>         ::= "|" | " " | "!" | "#" | "$" | "%" | "&" | "(" | ")" | "*" | "+" | "," | "-" | "." | "/" | ":" | ";" | ">" | "=" | "<" | "?" | "@" | "[" | "\" | "]" | "^" | "_" | "`" | "{" | "}" | "~"
<character1>     ::= <character> | "'"
<character2>     ::= <character> | '"'
<rule-name>      ::= <letter> | <rule-name> <rule-char>
<rule-char>      ::= <letter> | <digit> | "-"

改进

由于 BNF 缺失一些常见结构的简洁表达，通常有几种不同的扩展更常使用，见扩展 Backus–Naur 范式和增强 Backus–Naur 范式。